単純に音声を鳴らすだけなら前回のポストをご覧ください。

まず完成品をペタリ。

音声再生を複数配置するのはいろんなシーンで出てくると思います。その際に問題になる「Aの再生中にBが押されたら、Aの再生中にもう一度Aが押されたら…」といった複数再生時の時の処理を織り込んだプログラムを書いていきます。

では以下より手順を追って作成していきます。

【1】ファイルを用意する

上記のようにファイルを準備します。今回mp3はVoicePro様のフリー音源をお借りしました。

複数ファイルを呼び出す時に便利なのと、複数処理に便利なので設定ファイルとしてxmlも用意します。

【2】レイヤー＆フレームを用意

全てrootです。上から順に…

loading：いまローディング中です。をわかりやすく伝えるためのローディング画像（と進捗を表示するダイナミックテキストがセットになったMC）。

button：ボタンシンボル×5個。配置したいmp3のぶんだけ置くといいでしょう。

as/loading：swf自身のローディングと設定ファイル（config.xml）をロードするスクリプトを記述します。2フレーム目でxmlのデータを扱うので1フレーム目に記述します。

as/main：クリックイベントや再生制御などメインの処理を記述します。xmlのデータを扱うので確実にロードが完了している2フレーム目に記述します。

【3】ローディングムービークリップを配置

1フレーム目にローディング中を表すムービークリップを配置します。

子の構成は「ローディング画像（動画でもOK）」と「進捗を表示するダイナミックテキスト」です。

ムービークリップには”ins_nowloading”というインスタンス名を、その子にあるダイナミックテキストには”ins_loadtxt”というインスタンス名を付けてください。

【4】ボタンシンボルを作成

音声再生のトリガーとなるボタンシンボルを配置していきます。

適当に一つ作ってライブラリパネルで複製・一部変更で5個作ってステージに配置していきます。

インスタンス名で判定するので、それぞれ連番のインスタンス名を付けていきます。

【5】インスタンス名を付ける

上記スクリーンショットのようにムービークリップやボタンシンボルをクリックするとプロパティパネルにインスタンス名を入力するフィールドが表示されます。

ここにインスタンス名を入れましょう。インスタンス名はインスタンス名であることをプログラム中にわかりやすくするために命名ルールを決めて付けていきましょう。

ボクの場合は”ins_”と頭につけています。

【6】設定ファイルを作成する

xmlを設定ファイルとして使います。

as側でのコーディングが楽になるようにノード（独自タグ）はわかりやすくシンプル、かつ短いものを付けていきます。この際voice01、voice02と連番のタグにする必要はありません。as側でパースすることが出来るからです。

ノードの中身には音声ファイルまでのパスを記述してください。この際のパスは”xmlファイルやswfファイルから音声ファイルまでのパス”ではなく、”swfが表示されるhtmlから音声ファイルまでのパス”となる事に注意してください。

【7】ローディング処理を作る

swf自体のローディングと、設定ファイルの事前ロードのためにローディング処理を作っていきます。具体的なソースコードは以下です。

this.stop(); //2フレーム目に行かないようにまず止める

//XML用変数
var loader_xml:URLLoader = new URLLoader(); //xmlをロードするローダー
var my_XML:XML; //xmlを格納するflash側のXMLオブジェクト

//イベント登録
loaderInfo.addEventListener(ProgressEvent.PROGRESS, fnc_prog); //読み込み中
loaderInfo.addEventListener(Event.COMPLETE, fnc_comp); //読み込み完了

//読み込み中のイベント
var per:int; //進捗％を表示するための変数
function fnc_prog(e:ProgressEvent):void { //プログレスイベント毎に実行する
	per = e.bytesLoaded / e.bytesTotal * 100; //百分比でバイト総数と現在値を％に
	ins_nowloading.ins_loadtxt.text = String( per ) + "%"; //算出した％をダイナミックテキストに出力
}

//読み込み完了時のイベント
function fnc_comp(e:Event):void {
	loaderInfo.removeEventListener(ProgressEvent.PROGRESS, fnc_prog); //プログレスイベント削除
	loaderInfo.removeEventListener(Event.COMPLETE, fnc_comp); //コンプリートイベント削除
	loader_xml.load( new URLRequest( "config.xml" ) ); //設定ファイルロード開始
	loader_xml.addEventListener( Event.COMPLETE, fnc_xml_config ); //設定ファイルコンプリートイベント登録
}

//設定ファイル読み込み完了時のイベント
function fnc_xml_config(e):void{
	loader_xml.removeEventListener( Event.COMPLETE, fnc_xml_config ); //設定ファイルコンプリートイベント削除

	XML.ignoreWhitespace = true; //プログラムで邪魔になるXMLの余計な空白を削除
	my_XML = new XML(loader_xml.data); //6行目で作った変数にロードしたxmlの中身を入れる

	removeChild( ins_nowloading ); //ローディングオブジェクトを削除
	gotoAndStop( 2 ); //全てがロード完了したので2フレーム目に移動
}

ややこしいように見えるかもしれませんが、swf自身をロードして、終わったら設定ファイルをロードして、2フレーム目に移動する。それだけです。

【8】クリックイベントと音声再生処理を記述していく

まずはクリックイベントから。ボタンごとにイベントを設定すると煩雑なので、ステージ全体をイベントの対象として、クリックされた対象のインスタンス名で処理を振り分けます。自分はこのやりかたが効率が良いと思っていますが、他にもっといい方法があればそれでもいいと思います（我流なので何かお作法がおかしいかもしれません）。

“fnc_playsound”という関数がありますが、これは音声再生用の関数です、次の項目で説明していきます。

/*
クリックイベント
*/
stage.addEventListener(MouseEvent.CLICK, fnc_click); //ステージ自体にクリックイベントを登録
function fnc_click(e:Event):void{

	switch( e.target.name ){ //クリックされた対象のインスタンス名で処理を振り分け

		case "ins_btn01" :
			trace( "Voice01再生ボタンをクリックした" );
			fnc_playsound( 0 );
			break;

		case "ins_btn02" :
			trace( "Voice02再生ボタンをクリックした" );
			fnc_playsound( 1 );
			break;

		case "ins_btn03" :
			trace( "Voice03再生ボタンをクリックした" );
			fnc_playsound( 2 );
			break;

		case "ins_btn04" :
			trace( "Voice04再生ボタンをクリックした" );
			fnc_playsound( 3 );
			break;

		case "ins_btn05" :
			trace( "Voice05再生ボタンをクリックした" );
			fnc_playsound( 4 );
			break;

		default :
			trace( "設定外の対象をクリックした" );
			break;

	}

}

次に音声再生の処理を記述していきます。

/*
サウンドセット
*/
//サウンド用グローバル変数
var array_sound:Array = new Array(); //複数作るサウンドオブジェクトを格納する配列
var array_ch:Array = new Array(); //サウンドオブジェクトと対になり同じだけ必要になるサウンドチャンネルを格納する配列
var my_evesound:int; //現在再生している音声を判定するための変数

//ボイスを呼び出し
function fnc_sound_read():void{ //音声をロードして一回再生しておく（そうしないと以後の処理で扱いにくい）
	for( var i:int = 0; i < my_XML.sound.voice.length(); i++){

		//ロードして配列に格納
		array_sound[i]  = new Sound( new URLRequest( my_XML.sound.voice[i] ) ); //xmlをパースしてパスを抜き出してインスタンス化して作成
		array_ch[i] =  new SoundChannel; //サウンドチャンネルをインスタンス化して作成

		//エラー回避の為に一回再生して停止
		array_ch[i] = array_sound[i].play(); //再生
		array_ch[i].stop(); //停止

	}
}
fnc_sound_read();

/*
再生メソッド
*/
function fnc_playsound( arg_voice01:int ):void{
	my_evesound = arg_voice01; //引数からこれから再生される音声の格納番号を抜き出して判定用変数に格納
	if( array_ch[arg_voice01].position > 0 ){ //再生ヘッドをチェック（もし再生ヘッドが0より大きければ…つまり再生していれば）
		trace( "再生中だったので停止してイベント開放" );
		fnc_stopsound(); //停止処理を実行
		array_ch[my_evesound].removeEventListener(Event.SOUND_COMPLETE, fnc_soundcomp); //音声再生完了イベントを開放
	} else {
		trace( "再生中ではない" );
		fnc_stopsound(); //既に再生中の別の音声があった時のために停止処理を実行
		array_ch[arg_voice01] = array_sound[arg_voice01].play(); //引数に入っている数字を使い音声を再生
		array_ch[arg_voice01].addEventListener(Event.SOUND_COMPLETE, fnc_soundcomp); //音声再生完了イベントを登録
	}
}

/*
停止メソッド
*/
function fnc_stopsound():void{
	for( var i:int = 0; i < my_XML.sound.voice.length(); i++){ //xmlのノードから総数を取得してその回数実行
		array_ch[i].stop(); //まず停止
		array_ch[i] = array_sound[i].play( 0 ); //再生ヘッドを0に戻す
		array_ch[i].stop(); //戻して即時停止で0のままに
	}
}

/*
サウンドコンプリートハンドラ
*/
function fnc_soundcomp(e):void{ //再生完了まで別のボタンが押されなかった時のために再生ヘッドを元に戻すのに使う
	trace( "再生完了したので停止してイベント開放" );
	fnc_stopsound(); //停止処理を実行（停止処理には再生ヘッドを0に戻す処理も含まれる）
	array_ch[my_evesound].removeEventListener(Event.SOUND_COMPLETE, fnc_soundcomp); //音声再生完了イベントを開放
}

キモは"一回は再生しないとstop()メソッドでエラーが出る"ことと、"再生完了イベントを使い、再生ヘッドを0に戻す"ことの2つです。

複数ボタンがある場合、順番に押されてしまった時に重複して再生させないために、停止処理を作成しておきます（fnc_stopsoundという名前にしました）。そして、順番ではなく、同じボタンが押された時に音声が停止するのが自然だと思ったので現在再生中の音声と再生ボタンで呼び出される音声が一致して、かつその音声が再生中なら停止させる…という処理にしました。判定にはsoundchannelのプロパティpositionを使いました（positionは音声の現在の再生位置、つまり再生ヘッドを数字で返してくれます）。

単純にボタンだけの処理で終わらせてしまうと、"音声が自然に最後まで行って停止したとき"に不具合が起きます。as3の音声再生は音声が再生し終わっても再生ヘッドを0に戻してはくれないからです（テープのようなものです）。

ですので、音声再生と同時に再生した音声のsoundChannelにコンプリートイベントを発生させて、"音声が自然に最後まで行って停止したときに再生ヘッドを0に戻す"処理も記述しておきます。

以上で複数の音声を再生するボタンの作成は終了です。

この一連のやりかたを使えばゲームサイトやアニメ公式サイトのキャラクター紹介のサンプルボイスを再生するflashなどが簡単につくれるでしょう。ぜひご活用ください。そしてご活用いただけたらぜひ教えてください。

この記事で使っている音声はVoicePro様のフリー音源を活用させていただきました。ありがとうございました。

使用音源：VoicePro様

現実に帰る時間がなかなかとれない